M2: The Twisted Cubic

The Twisted Cubic

Let’s first define the coordinate ring of $ \P^3 $, where the twisted cubic lies:

i1 : kk = ZZ/32003;
i2 : R = kk[w, x, y, z]; -- this is a ring

Parametric Curve

This methods yields the twisted cubic as the ideal of a projective curve given parametrically by the map: \[ \begin{aligned} k[x,y,z] &\to k[t] \cr x &\mapsto t^3 \cr y &\mapsto t^2 \cr z &\mapsto t. \end{aligned} \]

i3 : monomialCurveIdeal(R, {1, 2, 3})

             2                    2
o3 = ideal (y  - x*z, x*y - w*z, x  - w*y)

o3 : Ideal of R

Determinantal Ideal

This method defines the twisted cubic as a determinantal ideal of $2\times 2$ minors, that is: \[ I = I_2 \begin{pmatrix} x & y & z \cr y & z & w \end{pmatrix} \]

i4 : minors(2, matrix {{x, y, z}, {y, z, w}})

               2                          2
o4 = ideal (- y  + x*z, w*x - y*z, w*y - z )

o4 : Ideal of R

Veronese Embedding

This method defines the twisted cubic as the kernel of the Veronese embedding of degree three on the projective line. That is:

i5 : kernel map(kk[s,t], R, {s^3, s^2*t, s*t^2, t^3})

             2                    2
o5 = ideal (y  - x*z, x*y - w*z, x  - w*y)

o5 : Ideal of R

Resolution and Betti Table

A minimal free resolution of the ideal defining the twisted cubic: \[ 0 \gets \mathcal O_C \gets \mathcal O_{\P^3} \gets 3\mathcal O_{\P^3}(-2) \gets 2\mathcal O_{\P^3}(-3) \gets 0 \]

i6 : res oo

      1      3      2
o6 = R  <-- R  <-- R  <-- 0
                           
     0      1      2      3

o6 : ChainComplex
i7 : betti oo

            0 1 2
o7 = total: 1 3 2
         0: 1 . .
         1: . 3 2

o7 : BettiTally